# Maintainer: enki <enki@sovbit.dev>
pkgname=sunstone
pkgver=0.1.0
pkgrel=1
pkgdesc="A native Linux desktop nostr client (GTK4 + libadwaita)"
arch=('x86_64')
url="https://codeberg.org/enki/sunstone"
license=('MIT')
depends=(
  'gtk4' 'libadwaita' 'libspelling'
  'gstreamer' 'gst-plugins-base' 'gst-plugins-good' 'gst-plugins-bad'
  'gst-plugin-gtk4' 'gst-libav'
  'openssl'
)
makedepends=('rust' 'cargo' 'pkgconf')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('SKIP')

# Codeberg archives extract to the repo name; adjust if you tag differently.
_srcdir="$pkgname"

prepare() {
  cd "$_srcdir"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "$_srcdir"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release --bin sunstone
}

package() {
  cd "$_srcdir"
  install -Dm755 "target/release/sunstone" "$pkgdir/usr/bin/sunstone"
  install -Dm644 "packaging/dev.sunstone.Sunstone.desktop" \
    "$pkgdir/usr/share/applications/sunstone.desktop"
  install -Dm644 "crates/sunstone-gtk/assets/sunstone-mark.svg" \
    "$pkgdir/usr/share/icons/hicolor/scalable/apps/sunstone.svg"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
